Register some properties in event handling

Question

I want to show several images to my application

            sourceAudioFile =(event.target as File);
            sourceAudioFile.data;

            var myLoader:Loader = new Loader(); 
            var url :URLRequest = new URLRequest("file:///" + sourceAudioFile.nativePath);
            myLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, onImageLoaded);
            myLoader.load(url);

Registration Listener

private function onImageLoaded(e:Event):void 
{
            var image : Bitmap= new Bitmap(e.target.content.bitmapData);
            image.scaleX = 0.5 ; 
            image.scaleY = 0.5 ; 
}

Is there any way by which i can add some custom values to Event.COMPLETE to know what type of image is being loaded.

like e.imageName , e.noOfImage which i can access in complete handler & provide values to it when i register this event.

Thanks in advance

score 1 · Answer 1 · edited May 23 '17 at 12:18

You can find out what ahs been loaded by checking LoaderInfo's url property

private function onImageLoaded(e:Event):void 
{
var cli:LoaderInfo = e.target as LoaderInfo;//you added listener to the contentLoaderInfo property
    trace(cli.url);//url of the media being loaded
    //do something with it
}

also in this SO question you can get more sophisticated asnwer to your problem:)

pass arguments to event listener

loxxy · Accepted Answer · 2012-12-03T07:58:02.460

1

Yes you can, try registering event like:

myLoader.contentLoaderInfo.addEventListener(Event.COMPLETE,function(e:Event){

  dispatchEvent(new CustomEvent(CustomEvent.COMPLETE, "<imageType>"));

}, false, 0, true);

And Add new Class, extending the Event class:

public class CustomEvent extends Event {

        public static const COMPLETE:String  = "CustomEventComplete";

        public var imageType:String = "";

        public function CustomEvent(type:String, imageType:String = "", bubbles:Boolean = false, cancelable:Boolean = false){

            super(type, bubbles, cancelable);

            this.imageType = imageType;
        }

        override public function clone():Event {

            return new CustomEvent(type, customTarget, bubbles, cancelable);
        }

    }

Now you can register for CustomEvent.COMPLETE & get the image type in the listener.

edited Dec 03 '12 at 07:58

answered Dec 03 '12 at 07:31

loxxy

12,990
2
25
56

1

why not? Use weak event listeners or call removeEventListener if listener is in scope.... – loxxy Dec 03 '12 at 07:45
how you will pass anonymous function to the removeEventLIstener? – Lukasz 'Severiaan' Grela Dec 03 '12 at 07:46
1

arguments.callee - http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/arguments.html#callee – loxxy Dec 03 '12 at 07:46
good - I thought that like caller it is not available anymore - thanks – Lukasz 'Severiaan' Grela Dec 03 '12 at 07:54
thanks for pointing out... I should have removed the listener, anyways. – loxxy Dec 03 '12 at 07:57

score 1 · Answer 3 · edited May 23 '17 at 12:12

Yes, there's a simple way:

myLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, onImageLoaded(imageName, noOfImage));
myLoader.load(url);

function onImageLoaded(imageName:String, noOfImage:int):Function {
  return function(e:Event):void {
    // Respective "e", "imageName" and "noOfImage" are available for you here.
  }
}

If you need to remove it later, change the first line to:

var functionOnImageLoaded:Function = onImageLoaded(imageName, noOfImage);
myLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, functionOnImageLoaded);

Then later just do it like this:

myLoader.contentLoaderInfo.removeEventListener(Event.COMPLETE, functionOnImageLoaded);

I've answered this before. See it here.

Register some properties in event handling

3 Answers3